Search All of the Math Forum:

Views expressed in these public forums are not endorsed by NCTM or The Math Forum.

Notice: We are no longer accepting new posts, but the forums will continue to be readable.

Topic: Maximize a single variable and solve for the rest
Replies: 5   Last Post: May 24, 2011 5:18 AM

 Messages: [ Previous | Next ]
 Bob Hanlon Posts: 2,604 Registered: 1/29/05
Re: Maximize a single variable and solve for the rest
Posted: May 21, 2011 6:44 AM

It makes no sense to Maximixe the LHS of an equation since it is fixed to be equal to the RHS. Presumably you are trying to maximize the variable c.

r1 = 3/4;
r2 = 1;

Maximize[{c, b == c*r1, h + s + b + d == 1, d == c*r2, h == s,
b + d <= 9/10}, {h, s, b, d, c}]

{18/35, {h -> 1/20, s -> 1/20, b -> 27/70, d -> 18/35, c -> 18/35}}

Solve[{b == c*r1, h + s + b + d == 1, d == c*r2, h == s, b + d <= 9/10}, {h,
s, b, d, c}, Reals] // Quiet

{{h -> ConditionalExpression[1 - (7*c)/4 + (1/2)*(-1 + (7*c)/4),
c <= 18/35],
s -> ConditionalExpression[(1/2)*(1 - (7*c)/4), c <= 18/35],
b -> ConditionalExpression[(3*c)/4, c <= 18/35],
d -> ConditionalExpression[c, c <= 18/35]}}

Since you want c maximized,

%[[1]] /. c -> 18/35

{h -> 1/20, s -> 1/20, b -> 27/70, d -> 18/35}

Bob Hanlon

---- Ramiro <ramiro.barrantes@gmail.com> wrote:

=============
Hello,

I have a problem where I would like to solve an equation (namely (h+s+b
+d==1) with some constraints, while maximizing for a related variable
"c" (c<=9). Please see below, any suggestions?

r1 = 3/4;
r2 = 1;
Block[{h, s, b, d, c},
NMaximize[{h + s + b + d,
b == c*r1 && h + s + b + d == 1 && d == c*r2 && h == s &&
b + d <= 0.9}, {h, s, b, d, c}]]

{1., {h -> 0.5, s -> 0.5, (3 c)/4 -> 0., c -> 0., c -> 0.}}

Should I be using NSolve?

Ramiro

Date Subject Author
5/20/11 Ramiro
5/21/11 Ramiro Barrantes-Reynolds
5/21/11 Peter Pein
5/21/11 Bob Hanlon
5/23/11 FranD
5/24/11 FranD