|
|
Re: 3d artifacts
Posted:
Jul 22, 2012 4:29 AM
|
|
I also suggested using Piecewise.
Clear[ww, f, g]
ww[t_, p_] = Piecewise[{{
{(10 + Cos[p]) Sin[2 t],
(10 + Cos[p + 2 Pi/3]) 15/10 Cos[t]/(1 + Sin[t]^2),
(10 + Cos[p - 2 Pi/3]) Sin[t]/(1 + Sin[t]^2)},
2 Pi <= t <= 4 Pi}},
{(10 + Cos[p]) Cos[t],
(10 + Cos[p + 2 Pi/3]) Sin[t],
(10 + Cos[p - 2 Pi/3]) Sin[2 t]}];
ParametricPlot3D[ww[t, p],
{t, 0, 4 Pi}, {p, 0, 2 Pi},
Boxed -> False,
Axes -> False,
ColorFunction -> "GreenBrownTerrain",
MeshFunctions -> {#3 &},
PlotPoints -> {35, 50}]
f[t_] = Piecewise[{
{(1 - Cos[2 t])/2,
-Pi/2 <= t <= Pi/2}},
(-1 + Cos[2 t])/2];
g[t_] = -Pi/2 + Mod[t, Pi];
ParametricPlot3D[{
(10 + Cos[p]) f[t] g[t],
(10 + Cos[p + 2 Pi/3]) g[t] g[t],
(10 + Cos[p - 2 Pi/3]) f[t]},
{t, -Pi, Pi}, {p, 0, 2 Pi},
Boxed -> False,
Axes -> False,
ColorFunction -> "GreenBrownTerrain",
MeshFunctions -> {#3 &},
PlotPoints -> {35, 50}]
Bob Hanlon
On Fri, Jul 20, 2012 at 3:49 AM, Roger Bagula <roger.bagula@gmail.com> wrote:
> Bob Hanlon
> You and Park both thought exceptions would work.
> Once add an tube function Parametric3D
> no longer performs the Exceptions it appears.
> I tried a tube program that usually works
> and then my triaxial tubes topological product method:
> Clear[ww, x, t, p, f, g]
> (* patched manifold function for Whitehead link*)
> ww[t_, p_] :=
> If[t >= 0 &&
> t < 2*Pi, {(10 + Cos[p])*Cos[t], (10 + Cos[p + 2*Pi/3])*
> Sin[t], (10 + Cos[p - 2*Pi/3])*Sin[2*t]},
> If[t >= 2*Pi &&
> t <= 4*Pi, {(10 + Cos[p])*
> Sin[2*t], (10 + Cos[p + 2*Pi/3])*15/
> 10 Cos[t]/(1 + Sin[t]^2), (10 + Cos[p - 2*Pi/3])*
> Sin[t]/(1 + Sin[t]^2)}, {(10 + Cos[p])*
> Cos[t], (10 + Cos[p + 2*Pi/3])*Sin[t], (10 + Cos[p - 2*Pi/3])*
> Sin[2*t]}]];
> ParametricPlot3D[ww[t, p], {t, 0, 4*Pi + 0.01}, {p, 0, 2*Pi},
> Exclusions -> {2 Pi, 4 Pi}, Boxed -> False, Axes -> False,
> ColorFunction -> "GreenBrownTerrain", MeshFunctions -> {#3 &},
> PlotPoints -> {35, 100}]
> ParametricPlot3D[ww[t, p], {t, 0, 4*Pi + 0.01}, {p, 0, 2*Pi},
> Exclusions -> Range[0, 4 \[Pi], \[Pi]/4], Boxed -> False,
> Axes -> False, ColorFunction -> "GreenBrownTerrain",
> MeshFunctions -> {#3 &}, PlotPoints -> {35, 100}]
> (* bicuspoid manifold definition*)
> f[t_] = If [
> t >= -Pi/2 && t <= Pi/2, (1 - Cos[2*t])/2, (-1 + Cos[2*t])/2];
> g[t_] = -Pi/2 + Mod[t, Pi];
> ParametricPlot3D[{(10 + Cos[p])*f[t]*g[t], (10 + Cos[p + 2*Pi/3])*
> g[t]*g[t], (10 + Cos[p - 2*Pi/3])*f[t]}, {t, -Pi, Pi}, {p, 0,
> 2*Pi}, Exclusions -> Range[-\[Pi], \[Pi], \[Pi]/4], Boxed -> False,
> Axes -> False, ColorFunction -> "GreenBrownTerrain",
> MeshFunctions -> {#3 &}, PlotPoints -> {35, 100}]
> ParametricPlot3D[{(10 + Cos[p])*f[t]*g[t], (10 + Cos[p + 2*Pi/3])*
> g[t]*g[t], (10 + Cos[p - 2*Pi/3])*f[t]}, {t, -Pi, Pi}, {p, 0,
> 2*Pi}, Exclusions -> {-Pi/2, Pi/2}, Boxed -> False, Axes -> False,
> ColorFunction -> "GreenBrownTerrain", MeshFunctions -> {#3 &},
> PlotPoints -> {35, 100}]
>
> On Monday, July 9, 2012 2:24:24 AM UTC-7, Bob Hanlon wrote:
>> Resent since this hasn't shown up.
>
|
|
