Search All of the Math Forum:

Views expressed in these public forums are not endorsed by Drexel University or The Math Forum.

Topic: Gamma Function - Bessel Function Identity
Replies: 3   Last Post: Sep 24, 2012 5:30 AM

 Messages: [ Previous | Next ]
 G. A. Edgar Posts: 2,504 Registered: 12/8/04
Re: Gamma Function - Bessel Function Identity
Posted: Sep 7, 2012 10:16 AM

In article
<kmsoileau@gmail.com> wrote:

> I have observed and proved the following identity for all x\ne 0 :
> $$> (I_{k-1}(x) +I_{k+1}(x) )I_{-k}(x) > -(I_{-k-1}(x)+I_{-k+1}(x))I_k(x) > = \frac{4 k}{x \Gamma (1-k) \Gamma (1+k)} >$$
>
> Is this well-known or trivially derived? Any comments will be appreciated.
> Thanks,
> Kerry M. Soileau
>

Easily derived in Maple. So presumably it follows from the known
identities for Bessel and Gamma function. Here it is...

First, we need the enhanced limits known to MultiSeries:
>restart;with(MultiSeries):

Here is the claim to be proved:
>claim:=(BesselI(k-1,x)+BesselI(k+1,x))*BesselI(-k,x)
- (BesselI(-k-1,x)+BesselI(-k+1,x))*BesselI(k,x)
=(4*k)/(x*GAMMA(1-k)*GAMMA(1+k));

claim := (BesselI(k-1, x)+BesselI(k+1, x))*BesselI(-k,
x)-(BesselI(-k-1, x)+BesselI(-k+1, x))*BesselI(k, x) =
4*k/(x*GAMMA(-k+1)*GAMMA(k+1))

Multiply by x so that the right-hand-side does not involve x:
>claim*x;

x*((BesselI(k-1, x)+BesselI(k+1, x))*BesselI(-k, x)-(BesselI(-k-1,
x)+BesselI(-k+1, x))*BesselI(k, x)) = 4*k/(GAMMA(-k+1)*GAMMA(k+1))

Here is the left-hand-side:
>L:=lhs(%);

L := x*((BesselI(k-1, x)+BesselI(k+1, x))*BesselI(-k, x)-(BesselI(-k-1,
x)+BesselI(-k+1, x))*BesselI(k, x))

Here is the right-hand-side:
>R:=rhs(%%);

R := 4*k/(GAMMA(-k+1)*GAMMA(k+1))

Since the right-hand-side does not involve x, we try to show that the
left-hand-side is also independent of x. Its derivative is zero:
>simplify(diff(L,x));

0

What is the constant value of the left-hand-side? It is undefined at
x=0, but the limit there is:
>simplify(limit(L,x=0)) assuming k::real;

4*sin(Pi*k)/Pi

On the other hand, the right-hand-side simplifies to the same thing:
>expand(simplify(R));

4*sin(Pi*k)/Pi

Date Subject Author
9/6/12 ksoileau
9/7/12 G. A. Edgar
9/7/12 Herman Rubin
9/24/12 Tom D