Date: Feb 25, 2013 2:19 AM
Author: Bob Hanlon
Subject: Re: A nonconventional ListContourPlot

x[a_, b_] = a*b;
y[a_, b_] = Cos[a^2 + b];
z[a_, b_] = Sin[a + b^2];

data = Table[
{x[i, j], y[i, j], z[i, j]},
{j, -1, 1, 0.1}, {i, -2, 2, 0.1}] //
Flatten[#, 1] &;

ListContourPlot[data]

ListContourPlot3D[data]

However, both ListContourPlot and ListContourPlot3D are difficult to
interpret for this complicated function. I recommend that you look at
the function with ParametricPlot3D.

Manipulate[
ParametricPlot3D[
Evaluate[
{x[a, b], y[a, b], z[a, b]}],
{a, -2, 2}, {b, -1, 1},
RegionFunction -> (#3 <= slice &),
BoundaryStyle ->
Directive[Black, Thick],
PlotRange ->
{{-2, 2}, {-1, 1}, {-1, 1}},
PlotPoints -> 50],
{{slice, 1}, -0.95, 1, 0.05,
Appearance -> "Labeled"}]


Bob Hanlon


On Sat, Feb 23, 2013 at 11:32 PM, Luiz Melo <lmelo@ufsj.edu.br> wrote:
> Good day,
>
> x[a_,b_] = a*b;
> y[a_,b_] = Cos[a^2 + b];
> z[a_,b_] = Sin[a + b^2];
>
> data = Table[{x[i,j], y[i,j], z[i,j]}, {j, -1, 1, 0.1}, {i, -2, 2, 0.1}];
>
> For the table above, is it possible to see a ListContourPlot of the z
> component as a function of x and y (the values of x and y on the
> horizontal and vertical axes, respectively)?
>
> Thank you in advance
> Luiz Melo
>