Drexel dragonThe Math ForumDonate to the Math Forum



Search All of the Math Forum:

Views expressed in these public forums are not endorsed by Drexel University or The Math Forum.


Math Forum » Discussions » Software » comp.soft-sys.math.mathematica

Topic: keep special functions unexpanded
Replies: 1   Last Post: Jul 21, 2013 4:16 AM

Advanced Search

Back to Topic List Back to Topic List Jump to Tree View Jump to Tree View  
David Park

Posts: 1,560
Registered: 5/19/07
Re: keep special functions unexpanded
Posted: Jul 21, 2013 4:16 AM
  Click to see the message monospaced in plain text Plain Text   Click to reply to this topic Reply

You could try something like this:

MakeBoxes[HoldForm[ChebyshevT[n_, x_]],
form : StandardForm | TraditionalForm] :=
InterpretationBox[#1, #2] & @@ {RowBox[{SubscriptBox["T",
MakeBoxes[n, form]], "[", MakeBoxes[x, form], "]"}],
ChebyshevT[n, x]}

Then with regular Mathematica:

fitFunctions = Table[HoldForm[ChebyshevT[ii, x]] /. ii -> i, {i, 0, 2}]
% // ReleaseHold

{Subscript[T, 0][x], Subscript[T, 1][x], Subscript[T, 2][x]}
{1, x, -1 + 2 x^2}

Or with Presentations you could use:

fitFunctions =
Table[ChebyshevT[i, x], {i, 0, 2}] // HoldOp[ChebyshevT]

with the same output.

Then with Fit you might use:

data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};
Fit[data, fitFunctions // ReleaseHold, x]
Cases[%, Alternatives @@
Flatten[{a_Real, a_ Rest@ReleaseHold[fitFunctions]}] ->
a].fitFunctions

0.773869 - 0.266332 x + 0.0954774 (-1 + 2 x^2)
0.773869 Subscript[T, 0][x] - 0.266332 Subscript[T, 1][x] + 0.0954774
Subscript[T, 2][x]


David Park
djmpark@comcast.net
http://home.comcast.net/~djmpark/index.html


From: metrologuy [mailto:takacs@bnl.gov]

I am trying to create a list of ChebyshevT[n,x] polynomials of different
orders to use as basis functions in a fitting routine. I want to keep the
list in the form that explicitly shows the order number. For example, I want
the list for order n=2 to look like this:
basislist={ChebyshevT[0,x],ChebyshevT[1,x],ChebyshevT[2,x]}.
If I use Table to generate the list, I get each function expanded into a
polynomial in x:

In[1]:= Table[ChebyshevT[i,x],{i,0,2}]

Out[1]= {1,x,-1+2 x^2}

How can I prevent the function from displaying the expanded form for each
value of n? If I use the unexpanded form in the Fit[] function, it works
just fine. But I lose the visual connection to the explicit order number in
the input form of the function. Any suggestions how to keep the "n" visible?





Point your RSS reader here for a feed of the latest messages in this topic.

[Privacy Policy] [Terms of Use]

© Drexel University 1994-2014. All Rights Reserved.
The Math Forum is a research and educational enterprise of the Drexel University School of Education.