Date: Feb 21, 2013 5:46 AM
Author: Bob Hanlon
Subject: Re: Is there a way to integrate and differentiate Erfi?

Works fine here

D[Erfi[x], x]

(2*E^x^2)/Sqrt[Pi]

% == Limit[(Erfi[x + d] - Erfi[x])/d, d -> 0]

True


Integrate[Erfi[x], x]

-(E^x^2/Sqrt[Pi]) + x*Erfi[x]

D[%, x] == Erfi[x]

True


Integrate[Erfi[x], {x, a, b}]

(-a)*Erfi[a] + (E^a^2 - E^b^2 + b*Sqrt[Pi]*Erfi[b])/
Sqrt[Pi]


SeriesCoefficient[Erfi[x], {x, 0, n}]

Piecewise[{{2/(n*Sqrt[Pi]*((1/2)*(-1 + n))!),
Mod[n, 2] == 1 && n >= 0}}, 0]

The series expansion for Erfi[x] is then

Sum[2/((2 n + 1) Sqrt[Pi] n!) x^(2 n + 1),
{n, 0, Infinity}]

Erfi[x]

Integrating term-by-term

Sum[2/((2 n + 1) Sqrt[Pi] n!)*
Integrate[x^(2 n + 1), x],
{n, 0, Infinity}] // Simplify

-((-1 + E^x^2)/Sqrt[Pi]) + x*Erfi[x]

Note that this differs from earlier result by an arbitrary constant of
integration but its derivative is still Erfi[x]

D[%, x] == Erfi[x]

True


Bob Hanlon


On Wed, Feb 20, 2013 at 10:28 PM, <eagles.g11.teams@gmail.com> wrote:
> It appears that Mathematica does not know how to integrate or differentiate the Erfi function. Am I correct? I am able to use Limit[(f(t+d)-f(t))/d, d -> 0] to get the derivative, but are there reasonable approaches to finding Integrate[Erfi]?
>
> Thanks!
>
> NS
>