Date: Jun 6, 2013 7:25 AM
Author: David Park
Subject: Re: Setting the Font Family and Font Size in BoxWhiskerChart

Use BaseStyle for ticks and regular plot labels.

BoxWhiskerChart[RandomVariate[NormalDistribution[0, 1], 100],
 BaseStyle -> {FontFamily -> "Palatino", FontSize -> 18},
 PlotLabel -> "Using BaseStyle for Font"]

If you also want to control the font in the Tooltip you will have to define
a LabelingFunction.

dataTooltip[data_] :=
 Module[{names = {"Max", "75%", "Median", "25%", "Min"}, values},
  values = {Max, Quantile[#, 3/4] &, Median, Quantile[#, 1/4] &, Min}[
     data] // Through;
  Grid[Transpose[{names, values}],
   Alignment -> {{Center, "."}, Automatic},
   Dividers -> All,
   Frame -> True]
  ] 

BoxWhiskerChart[RandomVariate[NormalDistribution[0, 1], 100],
 LabelingFunction -> (Placed[
     Style[dataTooltip[#], 18, FontFamily -> "Palatino"], Tooltip] &),
 BaseStyle -> {FontFamily -> "Palatino", FontSize -> 18},
 PlotLabel -> "Plot and Tooltip Fonts"] 

Not used here but the Presentations Application has a BoxWhiskerDraw
primitive so you can easily combine BoxWhisker elements with other
primitives and rotate/translate them to any desired locations.


David Park
djmpark@comcast.net 
http://home.comcast.net/~djmpark/index.html 





From: Gregory Lypny [mailto:gregory.lypny@videotron.ca] 


Hello everyone,

How can I change the font in a BoxWhiskerChart to Palatino?

Gregory